Download this file · Not for commercial use
  1. package
  2. {
  3. 	public class Example extends Sprite
  4. 	{
  5. 		public function Example() 
  6. 		{
  7. 			var sprite: AS2Sprite = new AS2Sprite;
  8. 			addChild( sprite.toSprite() );
  9. 			
  10. 			sprite.clip = new AS2Sprite;
  11. 			
  12. 			sprite.graphics.beginFill( 0xff0000, 1 );
  13. 			sprite.graphics.drawCircle( 0, 0, 10 );
  14. 			sprite.graphics.endFill();
  15. 			sprite._x = 10;
  16. 			sprite._y = 10;
  17. 			
  18. 			sprite.clip.graphics.beginFill( 0x00ff00, 1 );
  19. 			sprite.clip.graphics.drawCircle( 0, 0, 10 );
  20. 			sprite.clip.graphics.endFill();
  21. 			sprite.clip._x = 50;
  22. 			sprite.clip._y = 50;
  23. 			
  24. 			sprite.clip.clip2 = new AS2Sprite;
  25. 			sprite.clip.clip2.graphics.beginFill( 0x0000ff, 1 );
  26. 			sprite.clip.clip2.graphics.drawCircle( 0, 0, 10 );
  27. 			sprite.clip.clip2.graphics.endFill();
  28. 			sprite.clip.clip2._x = 50;
  29. 			sprite.clip.clip2._y = 50;
  30. 		}
  31. 	}
  32. }
  33.  
  34. import flash.utils.Proxy;
  35. import flash.utils.flash_proxy;
  36. import flash.display.DisplayObject;
  37. import flash.display.DisplayObjectContainer;
  38. import flash.display.Sprite;
  39.  
  40. dynamic class AS2Sprite extends Proxy
  41. {
  42. 	protected var sprite: AS2SpriteHandle;
  43.  
  44. 	public function AS2Sprite()
  45. 	{
  46. 		sprite = new AS2SpriteHandle( this );
  47. 	}
  48. 	
  49. 	flash_proxy override function callProperty( name: *, ... args ): *
  50. 	{
  51. 		return sprite[ name.toString() ].apply( sprite, args );
  52. 	}
  53. 	
  54. 	flash_proxy override function getProperty( name: * ): *
  55. 	{
  56. 		if ( sprite.hasOwnProperty( name.toString() ) )
  57. 		{
  58. 			return sprite[ name.toString() ];
  59. 		}
  60. 		else
  61. 		{
  62. 			var displayObject: DisplayObject = sprite.getChildByName( name.toString() );
  63. 			return ( displayObject is AS2SpriteHandle ) ? ( displayObject as AS2SpriteHandle ).handler : displayObject;
  64. 		}
  65. 	}
  66. 	
  67. 	flash_proxy override function setProperty( name: *, value: * ): void
  68. 	{
  69. 		if ( sprite.hasOwnProperty( name.toString() ) )
  70. 		{
  71. 			sprite[ name.toString() ] = value;
  72. 			return;
  73. 		}
  74. 		
  75. 		switch ( name.toString() )
  76. 		{
  77. 			case '_x':
  78. 				sprite.x = value;
  79. 				break;
  80. 				
  81. 			case '_y':
  82. 				sprite.y = value;
  83. 				break;
  84. 			
  85. 			case '_xscale':
  86. 				sprite.scaleX = value;
  87. 				break;
  88. 				
  89. 			case '_yscale':
  90. 				sprite.scaleY = value;
  91. 				break;
  92. 				
  93. 			default:
  94. 				var child: DisplayObject = sprite.getChildByName( name );
  95. 				var nextChild: DisplayObject = ( value is AS2Sprite ) ? ( value as AS2Sprite ).toDisplayObject() : value;
  96. 				
  97. 				if ( child != null )
  98. 				{
  99. 					if ( nextChild === child )
  100. 					{
  101. 						return;
  102. 					}
  103. 					else
  104. 					{
  105. 						sprite.removeChild( child );
  106. 					}
  107. 				}
  108. 				
  109. 				nextChild.name = name;
  110. 				sprite.addChild( nextChild );				
  111. 		}
  112. 	}
  113. 	
  114. 	flash_proxy override function deleteProperty( name: * ): Boolean
  115. 	{
  116. 		if ( sprite.hasOwnProperty( name.toString() ) )
  117. 		{
  118. 			return false;
  119. 		}
  120. 		
  121. 		switch ( name.toString() )
  122. 		{
  123. 			case '_x':
  124. 			case '_y':
  125. 			case '_xscale':
  126. 			case '_yscale':
  127. 				return false;
  128. 								
  129. 			default:
  130. 				var child: DisplayObject = sprite.getChildByName( name.toString() );
  131. 				
  132. 				if ( child != null )
  133. 				{
  134. 					sprite.removeChild( child );
  135. 					return true;
  136. 				}
  137. 				
  138. 				return false;
  139. 		}
  140. 	}
  141. 	
  142. 	public function toDisplayObject(): DisplayObject
  143. 	{
  144. 		return sprite;
  145. 	}
  146. 	
  147. 	public function toDisplayObjectContainer(): DisplayObjectContainer
  148. 	{
  149. 		return sprite;
  150. 	}
  151. 	
  152. 	public function toSprite(): Sprite
  153. 	{
  154. 		return sprite;
  155. 	}
  156. }
  157.  
  158. class AS2SpriteHandle extends Sprite
  159. {
  160. 	protected var _handler: AS2Sprite;
  161. 	
  162. 	public function AS2SpriteHandle( handler: AS2Sprite )
  163. 	{
  164. 		_handler = handler;
  165. 	}
  166. 	
  167. 	public function get handler(): AS2Sprite
  168. 	{
  169. 		return _handler;
  170. 	}
  171. } 
Unless otherwise expressly stated, all original material of whatever nature created by Joa D. Ebert and included in the je2050.de weblog and any related pages, including the weblog's archives, is licensed under a Creative Commons License.
Parsed in 0.138 seconds, using GeSHi 1.0.7.7